Новый пользователь

Для запуска необходимы права администратора на ПК.
На ПК была установлена ОС windows 10. В системе был активный пользователь user с правами администратора. Исходя из этого был написан следующий скрипт.

adduser.bat

rem добавление пользователя User1 пароль PASS - изменить на свой
net user User1 "PASS" /add /active:yes /times:all /fullname:"Администратор" /passwordreq:yes /passwordchg:yes
 
rem Добавить пользователя User1 в группу Администраторы
net localgroup "Администраторы" User1 /add
 
rem Удалить пользователя User1 из группы Пользователи
net localgroup "Пользователи" User1 /delete
 
rem Присвоить пользователю user удобочитаемый ник Учитель
net user user /active:yes /times:all /fullname:"Учитель" /passwordreq:no
 
rem Удалить пользователя user из группы Администраторы
net localgroup "Администраторы" user /delete
 
rem Добавить пользователя user в группу Пользователи
net localgroup "Пользователи" user /add
 
rem Пароль пользователей не имеет срока действия
WMIC USERACCOUNT WHERE "Name='user'" SET PasswordExpires=FALSE
WMIC USERACCOUNT WHERE "Name='User1'" SET PasswordExpires=FALSE
 
rem Установка корневых сертификатов
cd /d "%~dp0"
certutil -addstore "Root" "ca.root.crt"
certutil -addstore "Root" "russian_trusted_root_ca.cer"
certutil -addstore "CA" "russian_trusted_sub_ca.cer"
 
timeout /t 3
 
rem Переименование сетевого интерфейса LAN - изменить на свое
netsh interface set interface "Ethernet" newname="LAN"
 
rem Переименование имени диска C в System - изменить на свое
label c: System
 
rem Изменение рабочей группы компьютера MYGROUP - изменить на свое
wmic computersystem where name="%computername%" call joindomainorworkgroup name="MYGROUP"
 
rem Изминение имени компьютера, ввести имя компьютера согласно вашему плану номерации
@echo off
set /p "comp_name=Inter computer name: "
wmic computersystem where name="%COMPUTERNAME%" call rename "%comp_name%"
 
rem Настройка proxy
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /t REG_SZ /d 10.0.54.52:3128
timeout /t 3

Скрипт можно запускать два раза.Один раз от администратора системы, второй раз из под пользователя. Смысл в том, что настройки прокси прописываются только для пользователя под учетной записью которого запущен скрипт. При запуске от Администратора скрипт отработает полностью, если из под Пользователя, только настройки прокси, на все остальное будет не достаточно прав.

В скрипте могут быть не точности или ошибки, поэтому рекомендую запускать на тестовой машине.
Файлы сертификаты должны присутствовать в каталоге со скриптом.